plugins {
    id 'com.android.application'
    id 'kotlin-android'
}

def keystorePropertiesFile = rootProject.file("keystore.properties")
def keystoreProperties = new Properties()
keystoreProperties.load(new FileInputStream(keystorePropertiesFile))

android {
    compileSdkVersion COMPILE_SDK_VERSION
    buildToolsVersion BUILD_TOOLS_VERSION

    defaultConfig {
        applicationId "com.shzd.eyuangame"
        minSdkVersion MIN_SDK_VERSION
        targetSdkVersion TARGET_SDK_VERSION
        versionCode 1
        versionName "1.0"

        multiDexEnabled true

    }

    signingConfigs {
        config {
            keyAlias keystoreProperties['keyAlias']
            keyPassword keystoreProperties['keyPassword']
            storeFile file(keystoreProperties['storeFile'])
            storePassword keystoreProperties['storePassword']
            v1SigningEnabled true
            v2SigningEnabled true
        }
    }

    buildTypes {
        debug {
            minifyEnabled false
            signingConfig signingConfigs.config
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }

        release {
            minifyEnabled false
            signingConfig signingConfigs.config
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
    }

    lintOptions {
        abortOnError false
    }

    repositories {
        flatDir {
            dirs 'libs'
        }
    }

    dexOptions {
        preDexLibraries = false
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = "1.8"
    }
}

dependencies {

    if (PUBLISH_ENABLE) {
        if (REMOTE_LIBRARY) {
            implementation 'io.github.yyxxgame.sdk:eyuangame-sdk-ktx:1.0.0-alpha3'
        } else {
            api(name: 'library_core-release', ext: 'aar')

            implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-android:1.4.1'

            //mmkv
            implementation 'com.tencent:mmkv-static:1.2.10'

            //日志采集框架
            implementation 'io.github.suyghur.dolin:zap:1.0.0'

            implementation 'androidx.core:core-ktx:1.6.0'
            implementation 'androidx.fragment:fragment-ktx:1.3.5'
            implementation 'androidx.constraintlayout:constraintlayout:2.0.4'
            implementation 'com.google.android.material:material:1.4.0'
            implementation 'com.android.installreferrer:installreferrer:2.2'

            //google
            implementation 'com.google.android.play:core:1.10.0'
            implementation 'com.google.android.gms:play-services-auth:19.0.0'
            //4.0.0的billing库消耗商品会回调两次，后续在排查，先用3.0.3
            implementation "com.android.billingclient:billing-ktx:3.0.3"
            implementation 'com.google.firebase:firebase-analytics-ktx:19.0.0'
            implementation 'com.google.firebase:firebase-crashlytics-ktx:18.1.0'
            implementation 'com.google.firebase:firebase-crashlytics-ndk:18.1.0'

            //facebook
            implementation 'com.facebook.android:facebook-login:9.0.0'
            implementation 'com.facebook.android:facebook-android-sdk:8.2.0'

            //adjust
            implementation 'com.adjust.sdk:adjust-android:4.28.2'
        }
    } else {
        api project(':library_core')
    }
    debugImplementation 'com.squareup.leakcanary:leakcanary-android:2.7'
}