EYuanGameSdk-KTX/library_core/build.gradle

plugins {
    id 'com.android.library'
    id 'kotlin-android'
}

android {
    compileSdk rootProject.ext.android.compileSdk
    buildToolsVersion rootProject.ext.android.buildToolsVersion

    defaultConfig {
        minSdk rootProject.ext.android.minSdk
        targetSdk rootProject.ext.android.targetSdk

        externalNativeBuild {
            cmake {
                cppFlags '-std=c++11 -frtti -fexceptions -lz'
                abiFilters 'armeabi-v7a', 'arm64-v8a', 'x86', 'x86_64'
            }
        }

        ndk {
            // 设置支持的SO库架构
            abiFilters 'armeabi-v7a', 'arm64-v8a', 'x86', 'x86_64'
        }
    }


    buildTypes {
        release {
            minifyEnabled rootProject.ext.module.minifyEnabled
            proguardFiles 'proguard-rules.pro'
        }
    }

    buildFeatures {
        buildConfig false
    }

    lintOptions {
        abortOnError false
    }

    compileOptions {
        kotlinOptions.freeCompilerArgs += ['-module-name', "cn.yyxx.eyuangame.core"]
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = "1.8"
    }

    externalNativeBuild {
        cmake {
            path "CMakeLists.txt"
        }
    }

}

dependencies {
    //mmkv
    implementation 'com.tencent:mmkv-static:1.2.10'

    //日志采集框架
    implementation 'io.github.suyghur.dolin:zap:1.0.0'

    implementation 'androidx.core:core-ktx:1.7.0'
    implementation 'androidx.fragment:fragment-ktx:1.4.0'
    implementation 'androidx.constraintlayout:constraintlayout:2.1.3'
    implementation 'com.google.android.material:material:1.5.0'
    implementation 'com.android.installreferrer:installreferrer:2.2'

    //google
    implementation 'com.google.android.play:core:1.10.3'
    implementation 'com.google.android.gms:play-services-auth:20.0.1'
    //4.0.0的billing库消耗商品会回调两次，后续在排查，先用3.0.3
    implementation "com.android.billingclient:billing-ktx:3.0.3"
    implementation 'com.google.firebase:firebase-analytics-ktx:20.0.2'
    implementation 'com.google.firebase:firebase-crashlytics-ktx:18.2.6'
    implementation 'com.google.firebase:firebase-crashlytics-ndk:18.2.6'

    //facebook
    implementation 'com.facebook.android:facebook-android-sdk:11.2.0'

    //adjust
    implementation 'com.adjust.sdk:adjust-android:4.28.2'

    if (rootProject.ext.module.publish) {
        api files('../libs/eyuangamesdk_base_1.0.3.jar')
    } else {
        api project(':library_base')
    }

    switch (rootProject.ext.module.language){
        case 1:
            api project(':library_hk_language')
            break
        case 2:
            api project(':library_vn_language')
            break
    }
}

apply from: 'publish.gradle'